home *** CD-ROM | disk | FTP | other *** search
/ Skunkware 5 / Skunkware 5.iso / lib / emacs / 19.22 / lisp / texinfo.el < prev    next >
Lisp/Scheme  |  1993-11-20  |  29KB  |  742 lines
  1. ;;;; texinfo.el--major mode for editing Texinfo files.
  2. ;; Copyright (C) 1985, '88, '89, 
  3. ;;                '90, '91, '92, '93 Free Software Foundation, Inc.
  4.  
  5. ;;; Author: Robert J. Chassell          
  6. ;;; Maintainer: FSF
  7.  
  8. ;;; This file is part of GNU Emacs.
  9.  
  10. ;; GNU Emacs is free software; you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 2, or (at your option)
  13. ;; any later version.
  14.  
  15. ;; GNU Emacs is distributed in the hope that it will be useful,
  16. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18. ;; GNU General Public License for more details.
  19.  
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23.  
  24.  
  25. ;;; Autoloads:
  26.  
  27. (autoload 'makeinfo-region
  28.           "makeinfo"
  29.   "Make Info file from region of current Texinfo file, and switch to it.
  30.  
  31. This command does not offer the `next-error' feature since it would
  32. apply to a temporary file, not the original; use the `makeinfo-buffer'
  33. command to gain use of `next-error'."
  34.           t nil)
  35.  
  36. (autoload 'makeinfo-buffer
  37.           "makeinfo"
  38.   "Make Info file from current buffer.
  39.  
  40. Use the \\[next-error] command to move to the next error 
  41. \(if there are errors\)."
  42.           t nil)
  43.  
  44. (autoload 'kill-compilation
  45.           "compile"
  46.   "Kill the process made by the \\[compile] command."
  47.           t nil)
  48.  
  49. (autoload 'makeinfo-recenter-compilation-buffer
  50.           "makeinfo"
  51.   "Redisplay `*compilation*' buffer so most recent output can be seen.
  52. The last line of the buffer is displayed on
  53. line LINE of the window, or centered if LINE is nil."
  54.           t nil)
  55.  
  56. (autoload 'texinfo-make-menu
  57.           "texnfo-upd"
  58.   "Without any prefix argument, make or update a menu.
  59. Make the menu for the section enclosing the node found following point.
  60.  
  61. Non-nil argument (prefix, if interactive) means make or update menus
  62. for nodes within or part of the marked region.
  63.  
  64. Whenever a menu exists, and is being updated, the descriptions that
  65. are associated with node names in the pre-existing menu are
  66. incorporated into the new menu.  Otherwise, the nodes' section titles
  67. are inserted as descriptions."
  68.           t nil)
  69.  
  70. (autoload 'texinfo-all-menus-update
  71.           "texnfo-upd"
  72.   "Update every regular menu in a Texinfo file.
  73. Remove pre-existing master menu, if there is one.
  74.  
  75. If called with a non-nil argument, this function first updates all the
  76. nodes in the buffer before updating the menus."
  77.           t nil)
  78.  
  79. (autoload 'texinfo-master-menu
  80.           "texnfo-upd"
  81.   "Make a master menu for a whole Texinfo file.
  82. Non-nil argument (prefix, if interactive) means first update all
  83. existing nodes and menus.  Remove pre-existing master menu, if there is one.
  84.  
  85. This function creates a master menu that follows the top node.  The
  86. master menu includes every entry from all the other menus.  It
  87. replaces any existing ordinary menu that follows the top node.
  88.  
  89. If called with a non-nil argument, this function first updates all the
  90. menus in the buffer (incorporating descriptions from pre-existing
  91. menus) before it constructs the master menu.
  92.  
  93. The function removes the detailed part of an already existing master
  94. menu.  This action depends on the pre-exisitng master menu using the
  95. standard `texinfo-master-menu-header'.
  96.  
  97. The master menu has the following format, which is adapted from the
  98. recommendation in the Texinfo Manual:
  99.  
  100.    * The first part contains the major nodes in the Texinfo file: the
  101.      nodes for the chapters, chapter-like sections, and the major
  102.      appendices.  This includes the indices, so long as they are in
  103.      chapter-like sections, such as unnumbered sections.
  104.  
  105.    * The second and subsequent parts contain a listing of the other,
  106.      lower level menus, in order.  This way, an inquirer can go
  107.      directly to a particular node if he or she is searching for
  108.      specific information.
  109.  
  110. Each of the menus in the detailed node listing is introduced by the
  111. title of the section containing the menu."
  112.           t nil)
  113.  
  114. (autoload 'texinfo-indent-menu-description
  115.           "texnfo-upd"
  116.   "Indent every description in menu following point to COLUMN.  
  117. Non-nil argument (prefix, if interactive) means indent every
  118. description in every menu in the region.  Does not indent second and
  119. subsequent lines of a multi-line description."
  120.           t nil)
  121.  
  122. (autoload 'texinfo-insert-node-lines
  123.           "texnfo-upd"
  124.   "Insert missing `@node' lines in region of Texinfo file.
  125. Non-nil argument (prefix, if interactive) means also to insert the
  126. section titles as node names; and also to insert the section titles as
  127. node names in pre-existing @node lines that lack names."
  128.           t nil)
  129.  
  130. (autoload 'texinfo-start-menu-description
  131.           "texnfo-upd"
  132.   "In this menu entry, insert the node's section title as a description. 
  133. Position point at beginning of description ready for editing.
  134. Do not insert a title if the line contains an existing description.
  135.  
  136. You will need to edit the inserted text since a useful description
  137. complements the node name rather than repeats it as a title does."
  138.           t nil)
  139.  
  140. (autoload 'texinfo-multiple-files-update
  141.           "texnfo-upd"
  142.   "Update first node pointers in each file included in OUTER-FILE;
  143. create or update main menu in the outer file that refers to such nodes. 
  144. This does not create or update menus or pointers within the included files.
  145.  
  146. With optional MAKE-MASTER-MENU argument (prefix arg, if interactive),
  147. insert a master menu in OUTER-FILE.  This does not create or update
  148. menus or pointers within the included files.
  149.  
  150. With optional UPDATE-EVERYTHING argument (numeric prefix arg, if
  151. interactive), update all the menus and all the `Next', `Previous', and
  152. `Up' pointers of all the files included in OUTER-FILE before inserting
  153. a master menu in OUTER-FILE.
  154.  
  155. The command also updates the `Top' level node pointers of OUTER-FILE.
  156.  
  157. Notes: 
  158.  
  159.   * this command does NOT save any files--you must save the
  160.     outer file and any modified, included files.
  161.  
  162.   * except for the `Top' node, this command does NOT handle any
  163.     pre-existing nodes in the outer file; hence, indices must be
  164.     enclosed in an included file.
  165.  
  166. Requirements:
  167.  
  168.   * each of the included files must contain exactly one highest
  169.     hierarchical level node, 
  170.   * this highest node must be the first node in the included file,
  171.   * each highest hierarchical level node must be of the same type.
  172.  
  173. Thus, normally, each included file contains one, and only one,
  174. chapter."
  175.           t nil)
  176.  
  177.  
  178. ;;; Code:
  179.  
  180. ;;; Don't you dare insert any `require' calls at top level in this file--rms.
  181.  
  182. ;;; Syntax table
  183.  
  184. (defvar texinfo-mode-syntax-table nil)
  185.  
  186. (if texinfo-mode-syntax-table
  187.     nil
  188.   (setq texinfo-mode-syntax-table (make-syntax-table))
  189.   (modify-syntax-entry ?\" " " texinfo-mode-syntax-table)
  190.   (modify-syntax-entry ?\\ " " texinfo-mode-syntax-table)
  191.   (modify-syntax-entry ?@ "\\" texinfo-mode-syntax-table)
  192.   (modify-syntax-entry ?\^q "\\" texinfo-mode-syntax-table)
  193.   (modify-syntax-entry ?\[ "(]" texinfo-mode-syntax-table)
  194.   (modify-syntax-entry ?\] ")[" texinfo-mode-syntax-table)
  195.   (modify-syntax-entry ?{ "(}" texinfo-mode-syntax-table)
  196.   (modify-syntax-entry ?} "){" texinfo-mode-syntax-table)
  197.   (modify-syntax-entry ?\' "w" texinfo-mode-syntax-table))
  198.  
  199.  
  200. ;;; Keybindings
  201. (defvar texinfo-mode-map nil)
  202.  
  203. ;;; Keys common both to Texinfo mode and to TeX shell.
  204.  
  205. (defun texinfo-define-common-keys (keymap)
  206.   "Define the keys both in Texinfo mode and in the texinfo-tex-shell."
  207.   (define-key keymap "\C-c\C-t\C-k"    'tex-kill-job)
  208.   (define-key keymap "\C-c\C-t\C-x"    'texinfo-quit-job)
  209.   (define-key keymap "\C-c\C-t\C-l"    'tex-recenter-output-buffer)
  210.   (define-key keymap "\C-c\C-t\C-d"    'texinfo-delete-from-print-queue)
  211.   (define-key keymap "\C-c\C-t\C-q"    'tex-show-print-queue)
  212.   (define-key keymap "\C-c\C-t\C-p"    'texinfo-tex-print)
  213.   (define-key keymap "\C-c\C-t\C-i"    'texinfo-texindex)
  214.  
  215.   (define-key keymap "\C-c\C-t\C-r"    'texinfo-tex-region)
  216.   (define-key keymap "\C-c\C-t\C-b"    'texinfo-tex-buffer))
  217.  
  218. ;; Mode documentation displays commands in reverse order 
  219. ;; from how they are listed in the texinfo-mode-map.
  220.  
  221. (if texinfo-mode-map
  222.     nil
  223.   (setq texinfo-mode-map (make-sparse-keymap))
  224.  
  225.   ;; bindings for `texnfo-tex.el'
  226.   (texinfo-define-common-keys texinfo-mode-map)
  227.  
  228.   ;; bindings for `makeinfo.el'
  229.   (define-key texinfo-mode-map "\C-c\C-m\C-k" 'kill-compilation)
  230.   (define-key texinfo-mode-map "\C-c\C-m\C-l" 
  231.     'makeinfo-recenter-compilation-buffer)
  232.   (define-key texinfo-mode-map "\C-c\C-m\C-r" 'makeinfo-region)
  233.   (define-key texinfo-mode-map "\C-c\C-m\C-b" 'makeinfo-buffer)
  234.  
  235.   ; Bindings for texinfmt.el.
  236.   (define-key texinfo-mode-map "\C-c\C-e\C-r"    'texinfo-format-region)
  237.   (define-key texinfo-mode-map "\C-c\C-e\C-b"    'texinfo-format-buffer)
  238.  
  239.   ;; bindings for updating nodes and menus
  240.  
  241.   (define-key texinfo-mode-map "\C-c\C-um"   'texinfo-master-menu)
  242.  
  243.   (define-key texinfo-mode-map "\C-c\C-u\C-m"   'texinfo-make-menu)
  244.   (define-key texinfo-mode-map "\C-c\C-u\C-n"   'texinfo-update-node)
  245.   (define-key texinfo-mode-map "\C-c\C-u\C-e"   'texinfo-every-node-update)
  246.   (define-key texinfo-mode-map "\C-c\C-u\C-a"   'texinfo-all-menus-update)
  247.  
  248.   (define-key texinfo-mode-map "\C-c\C-s"     'texinfo-show-structure)
  249.  
  250.   (define-key texinfo-mode-map "\C-c}"        'up-list)
  251.   (define-key texinfo-mode-map "\C-c]"        'up-list)
  252.   (define-key texinfo-mode-map "\C-c{"        'texinfo-insert-braces)
  253.  
  254.   ;; bindings for inserting strings
  255.  
  256.   (define-key texinfo-mode-map "\C-c\C-c\C-d" 'texinfo-start-menu-description)
  257.  
  258.   (define-key texinfo-mode-map "\C-c\C-cv"    'texinfo-insert-@var)
  259.   (define-key texinfo-mode-map "\C-c\C-ct"    'texinfo-insert-@table)
  260.   (define-key texinfo-mode-map "\C-c\C-cs"    'texinfo-insert-@samp)
  261.   (define-key texinfo-mode-map "\C-c\C-co"    'texinfo-insert-@noindent)
  262.   (define-key texinfo-mode-map "\C-c\C-cn"    'texinfo-insert-@node)
  263.   (define-key texinfo-mode-map "\C-c\C-ck"    'texinfo-insert-@kbd)
  264.   (define-key texinfo-mode-map "\C-c\C-ci"    'texinfo-insert-@item)
  265.   (define-key texinfo-mode-map "\C-c\C-cf"    'texinfo-insert-@file)
  266.   (define-key texinfo-mode-map "\C-c\C-cx"    'texinfo-insert-@example)
  267.   (define-key texinfo-mode-map "\C-c\C-ce"    'texinfo-insert-@end)
  268.   (define-key texinfo-mode-map "\C-c\C-cd"    'texinfo-insert-@dfn)
  269.   (define-key texinfo-mode-map "\C-c\C-cc"    'texinfo-insert-@code))
  270.  
  271.  
  272. ;;; Texinfo mode
  273.  
  274. (defvar texinfo-chapter-level-regexp 
  275.   "chapter\\|unnumbered \\|appendix \\|majorheading\\|chapheading"
  276.   "Regular expression matching Texinfo chapter-level headings.
  277. This does not match `@node' and does not match the `@top' command.")
  278.  
  279. ;;;###autoload
  280. (defun texinfo-mode ()
  281.   "Major mode for editing Texinfo files.
  282.  
  283.   It has these extra commands:
  284. \\{texinfo-mode-map}
  285.  
  286.   These are files that are used as input for TeX to make printed manuals
  287. and also to be turned into Info files with \\[makeinfo-buffer] or
  288. the `makeinfo' program.  These files must be written in a very restricted and
  289. modified version of TeX input format.
  290.  
  291.   Editing commands are like text-mode except that the syntax table is
  292. set up so expression commands skip Texinfo bracket groups.  To see
  293. what the Info version of a region of the Texinfo file will look like,
  294. use \\[makeinfo-region], which runs `makeinfo' on the current region.
  295.  
  296.   You can show the structure of a Texinfo file with \\[texinfo-show-structure].
  297. This command shows the structure of a Texinfo file by listing the
  298. lines with the @-sign commands for @chapter, @section, and the like.
  299. These lines are displayed in another window called the *Occur* window.
  300. In that window, you can position the cursor over one of the lines and
  301. use \\[occur-mode-goto-occurrence], to jump to the corresponding spot
  302. in the Texinfo file.
  303.  
  304.   In addition, Texinfo mode provides commands that insert various
  305. frequently used @-sign commands into the buffer.  You can use these
  306. commands to save keystrokes.  And you can insert balanced braces with
  307. \\[texinfo-insert-braces] and later use the command \\[up-list] to
  308. move forward past the closing brace.
  309.  
  310. Also, Texinfo mode provides functions for automatically creating or
  311. updating menus and node pointers.  These functions
  312.  
  313.   * insert the `Next', `Previous' and `Up' pointers of a node,
  314.   * insert or update the menu for a section, and
  315.   * create a master menu for a Texinfo source file.
  316.  
  317. Here are the functions:
  318.  
  319.     texinfo-update-node                \\[texinfo-update-node]
  320.     texinfo-every-node-update          \\[texinfo-every-node-update]
  321.     texinfo-sequential-node-update 
  322.  
  323.     texinfo-make-menu                  \\[texinfo-make-menu]
  324.     texinfo-all-menus-update           \\[texinfo-all-menus-update]
  325.     texinfo-master-menu
  326.  
  327.     texinfo-indent-menu-description (column &optional region-p)
  328.  
  329. The `texinfo-column-for-description' variable specifies the column to
  330. which menu descriptions are indented. 
  331.  
  332. Passed an argument (a prefix argument, if interactive), the
  333. `texinfo-update-node' and `texinfo-make-menu' functions do their jobs
  334. in the region.
  335.  
  336. To use the updating commands, you must structure your Texinfo file
  337. hierarchically, such that each `@node' line, with the exception of the
  338. Top node, is accompanied by some kind of section line, such as an
  339. `@chapter' or `@section' line.
  340.  
  341. If the file has a `top' node, it must be called `top' or `Top' and
  342. be the first node in the file.
  343.  
  344. Entering Texinfo mode calls the value of text-mode-hook, and then the
  345. value of texinfo-mode-hook."
  346.   (interactive)
  347.   (text-mode)
  348.   (setq mode-name "Texinfo")
  349.   (setq major-mode 'texinfo-mode)
  350.   (use-local-map texinfo-mode-map)
  351.   (set-syntax-table texinfo-mode-syntax-table)
  352.   (make-local-variable 'page-delimiter)
  353.   (setq page-delimiter 
  354.         (concat 
  355.          "^@node [ \t]*[Tt]op\\|^@\\(" 
  356.          texinfo-chapter-level-regexp 
  357.          "\\)"))
  358.   (make-local-variable 'require-final-newline)
  359.   (setq require-final-newline t)
  360.   (make-local-variable 'indent-tabs-mode)
  361.   (setq indent-tabs-mode nil)
  362.   (make-local-variable 'paragraph-separate)
  363.   (setq paragraph-separate (concat "^\b\\|^@[a-zA-Z]*[ \n]\\|" paragraph-separate))
  364.   (make-local-variable 'paragraph-start)
  365.   (setq paragraph-start (concat "^\b\\|^@[a-zA-Z]*[ \n]\\|" paragraph-start))
  366.   (make-local-variable 'fill-column)
  367.   (setq fill-column 72)
  368.   (make-local-variable 'comment-start)
  369.   (setq comment-start "@c ")
  370.   (make-local-variable 'comment-start-skip)
  371.   (setq comment-start-skip "@c +")
  372.   (make-local-variable 'words-include-escapes)
  373.   (setq words-include-escapes t)
  374.   (make-local-variable 'tex-start-of-header)
  375.   (setq tex-start-of-header "%**start")
  376.   (make-local-variable 'tex-end-of-header)
  377.   (setq tex-end-of-header "%**end")
  378.   (run-hooks 'text-mode-hook 'texinfo-mode-hook))
  379.  
  380.  
  381. ;;; Insert string commands
  382.  
  383. (defconst texinfo-environment-regexp
  384.   "^@\\(f?table\\|enumerate\\|itemize\\|ifinfo\\|iftex\\|example\\|quotation\\|lisp\\|smallexample\\|smalllisp\\|display\\|format\\|flushleft\\|flushright\\|ignore\\|group\\|tex\\|cartouche\\|end\\)"
  385.   "Regexp for environment-like TexInfo list commands.
  386. Subexpression 1 is what goes into the corresponding `@end' statement.")
  387.  
  388. ;; The following texinfo-insert-@end command not only inserts a SPC
  389. ;; after the @end, but tries to find out what belongs there.  It is
  390. ;; not very smart: it does not understand nested lists.
  391.  
  392. (defun texinfo-insert-@end ()
  393.   "Insert the matching `@end' for the last Texinfo command that needs one."
  394.   (interactive)
  395.   (let ((depth 1) string)
  396.     (save-excursion
  397.       (while (and (> depth 0)
  398.           (re-search-backward texinfo-environment-regexp nil t)
  399.     (if (looking-at "@end")
  400.         (setq depth (1+ depth))
  401.       (setq depth (1- depth)))))
  402.       (looking-at texinfo-environment-regexp)
  403.       (setq string
  404.         (buffer-substring (match-beginning 1)
  405.                   (match-end 1))))
  406.     (insert "@end ")
  407.     (if string (insert string "\n"))))
  408.  
  409. ;; The following insert commands accept a prefix arg N, which is the
  410. ;; number of words (actually s-exprs) that should be surrounded by
  411. ;; braces.  Thus you can first paste a variable name into a .texinfo
  412. ;; buffer, then say C-u 1 C-c C-c v at the beginning of the just
  413. ;; pasted variable name to put @var{...} *around* the variable name.
  414. ;; Operate on previous word or words with negative arg.
  415.  
  416. ;; These commands use texinfo-insert-@-with-arg
  417. (defun texinfo-insert-@-with-arg (string &optional arg)
  418.   (if arg 
  419.       (progn
  420.         (setq arg (prefix-numeric-value arg))
  421.         (if (< arg 0)
  422.             (progn
  423.               (skip-chars-backward " \t\n\r\f")
  424.               (save-excursion
  425.                 (forward-sexp arg)
  426.                 (insert "@" string "{"))
  427.               (insert "}"))
  428.           (skip-chars-forward " \t\n\r\f")
  429.           (insert "@" string "{")
  430.           (forward-sexp arg)
  431.           (insert "}")))
  432.     (insert "@" string "{}")
  433.     (backward-char)))
  434.  
  435. (defun texinfo-insert-braces ()
  436.   "Make a pair of braces and be poised to type inside of them.
  437. Use \\[up-list] to move forward out of the braces."
  438.   (interactive)
  439.   (insert "{}")
  440.   (backward-char))
  441.  
  442. (defun texinfo-insert-@code (&optional arg)
  443.   "Insert a `@code{...}' command in a Texinfo buffer.
  444. A numeric argument says how many words the braces should surround.
  445. The default is not to surround any existing words with the braces."
  446.   (interactive "P")
  447.   (texinfo-insert-@-with-arg "code" arg))
  448.  
  449. (defun texinfo-insert-@dfn (&optional arg)
  450.   "Insert a `@dfn{...}' command in a Texinfo buffer.
  451. A numeric argument says how many words the braces should surround.
  452. The default is not to surround any existing words with the braces."
  453.   (interactive "P")
  454.   (texinfo-insert-@-with-arg "dfn" arg))
  455.  
  456. (defun texinfo-insert-@example ()
  457.   "Insert the string `@example' in a Texinfo buffer."
  458.   (interactive)
  459.   (insert "@example\n"))
  460.  
  461. (defun texinfo-insert-@file (&optional arg)
  462.   "Insert a `@file{...}' command in a Texinfo buffer.
  463. A numeric argument says how many words the braces should surround.
  464. The default is not to surround any existing words with the braces."
  465.   (interactive "P")
  466.   (texinfo-insert-@-with-arg "file" arg))
  467.  
  468. (defun texinfo-insert-@item ()
  469.   "Insert the string `@item' in a Texinfo buffer."
  470.   (interactive)
  471.   (insert "@item")
  472.   (newline))
  473.  
  474. (defun texinfo-insert-@kbd (&optional arg)
  475.   "Insert a `@kbd{...}' command in a Texinfo buffer.
  476. A numeric argument says how many words the braces should surround.
  477. The default is not to surround any existing words with the braces."
  478.   (interactive "P")
  479.   (texinfo-insert-@-with-arg "kbd" arg))
  480.  
  481. (defun texinfo-insert-@node ()
  482.   "Insert the string `@node' in a Texinfo buffer.
  483. This also inserts on the following line a comment indicating
  484. the order of arguments to @node."
  485.   (interactive)
  486.   (insert "@node \n@comment  node-name,  next,  previous,  up")
  487.   (forward-line -1)
  488.   (forward-char 6))
  489.  
  490. (defun texinfo-insert-@noindent ()
  491.   "Insert the string `@noindent' in a Texinfo buffer."
  492.   (interactive)
  493.   (insert "@noindent\n"))
  494.  
  495. (defun texinfo-insert-@samp (&optional arg)
  496.   "Insert a `@samp{...}' command in a Texinfo buffer.
  497. A numeric argument says how many words the braces should surround.
  498. The default is not to surround any existing words with the braces."
  499.   (interactive "P")
  500.   (texinfo-insert-@-with-arg "samp" arg))
  501.  
  502. (defun texinfo-insert-@table (&optional arg)
  503.   "Insert the string `@table' in a Texinfo buffer."
  504.   (interactive "P")
  505.   (insert "@table "))
  506.  
  507. (defun texinfo-insert-@var (&optional arg)
  508.   "Insert a `@var{}' command in a Texinfo buffer.
  509. A numeric argument says how many words the braces should surround.
  510. The default is not to surround any existing words with the braces."
  511.   (interactive "P")
  512.   (texinfo-insert-@-with-arg "var" arg))
  513.  
  514. ;;; Texinfo file structure
  515.  
  516. (defun texinfo-show-structure (&optional nodes-too) 
  517.   "Show the structure of a Texinfo file.
  518. List the lines in the file that begin with the @-sign commands for
  519. @chapter, @section, and the like.
  520.  
  521. With optional argument (prefix if interactive), list both the lines
  522. with @-sign commands for @chapter, @section, and the like, and list
  523. @node lines.
  524.  
  525. Lines with structuring commands beginning in them are displayed in
  526. another buffer named `*Occur*'.  In that buffer, you can move point to
  527. one of those lines and then use \\<occur-mode-map>\\[occur-mode-goto-occurrence], 
  528. to jump to the corresponding spot in the Texinfo source file."
  529.  
  530.   (interactive "P")
  531.   (require 'texnfo-upd)
  532.   (save-excursion 
  533.     (goto-char (point-min))
  534.     (if nodes-too
  535.         (occur (concat "\\(^@node\\)\\|" texinfo-section-types-regexp))
  536.       (occur texinfo-section-types-regexp)))
  537.   (pop-to-buffer "*Occur*")
  538.   (goto-char (point-min))
  539.   (flush-lines "-----")
  540.   ;; Now format the "*Occur*" buffer to show the structure.
  541.   ;; Thanks to ceder@signum.se (Per Cederqvist)
  542.   (goto-char (point-max))
  543.   (let ((margin 5))
  544.     (while (re-search-backward "^ *[0-9]*:" nil 0)
  545.       (re-search-forward ":")
  546.       (setq margin
  547.             (cond
  548.              ((looking-at
  549.                (concat "@\\(" texinfo-chapter-level-regexp "\\)")) 5)
  550.              ;; ((looking-at "@chapter ") 5)
  551.              ;; ((looking-at "@unnumbered ") 5)
  552.              ;; ((looking-at "@appendix ") 5)
  553.              ;; ((looking-at "@majorheading ") 5)
  554.              ;; ((looking-at "@chapheading ") 5)
  555.  
  556.              ((looking-at
  557.                (concat "@\\(" texinfo-section-level-regexp "\\)")) 9)
  558.              ;; ((looking-at "@section ") 9)
  559.              ;; ((looking-at "@unnumberedsec ") 9)
  560.              ;; ((looking-at "@appendixsec ") 9)
  561.              ;; ((looking-at "@heading ") 9)
  562.  
  563.              ((looking-at 
  564.                (concat "@\\(" texinfo-subsection-level-regexp "\\)")) 13)
  565.              ;; ((looking-at "@subsection ") 13)
  566.              ;; ((looking-at "@unnumberedsubsec ") 13)
  567.              ;; ((looking-at "@appendixsubsec ") 13)
  568.              ;; ((looking-at "@subheading ") 13)
  569.  
  570.              ((looking-at 
  571.                (concat "@\\(" texinfo-subsection-level-regexp "\\)")) 13)
  572.              ;; ((looking-at "@subsubsection ") 17)
  573.              ;; ((looking-at "@unnumberedsubsubsec ") 17)
  574.              ;; ((looking-at "@appendixsubsubsec ") 17)
  575.              ;; ((looking-at "@subsubheading ") 17)
  576.              (t margin)))
  577.       (indent-to-column margin)
  578.       (beginning-of-line))))
  579.  
  580. ;;; The  tex  and  print  function definitions:
  581.  
  582. (defvar texinfo-texi2dvi-command "texi2dvi"
  583.   "*Command used by `texinfo-tex-buffer' to run TeX and texindex on a buffer.")
  584.  
  585. (defvar texinfo-tex-command "tex"
  586.   "*Command used by `texinfo-tex-region' to run TeX on a region.")
  587.  
  588. (defvar texinfo-texindex-command "texindex"
  589.   "*Command used by `texinfo-texindex' to sort unsorted index files.")
  590.  
  591. (defvar texinfo-delete-from-print-queue-command "lprm"
  592.   "*Command string used to delete a job from the line printer queue.
  593. Command is used by \\[texinfo-delete-from-print-queue] based on
  594. number provided by a previous \\[tex-show-print-queue]
  595. command.")
  596.  
  597. (defvar texinfo-tex-trailer "@bye"
  598.   "String appended after a region sent to TeX by `texinfo-tex-region'.")
  599.  
  600. (defun texinfo-tex-region (beg end)
  601.   "Run TeX on the current region.
  602. This works by writing a temporary file (`tex-zap-file') in the directory
  603. that is the value of `tex-directory', then running TeX on that file.
  604.  
  605. The first line of the buffer is copied to the
  606. temporary file; and if the buffer has a header, it is written to the
  607. temporary file before the region itself.  The buffer's header is all lines
  608. between the strings defined by `tex-start-of-header' and `tex-end-of-header'
  609. inclusive.  The header must start in the first 100 lines.
  610.  
  611. The value of `texinfo-tex-trailer' is appended to the temporary file after the region."
  612.   (interactive "r")
  613.   (require 'tex-mode)
  614.   (if (get-buffer "*tex-shell*")
  615.       (tex-kill-job)
  616.     (tex-start-shell))
  617.   (or tex-zap-file (setq tex-zap-file (make-temp-name "#tz")))
  618.   (let ((tex-out-file (concat tex-zap-file ".tex"))
  619.     (temp-buffer (get-buffer-create " tex-Output-Buffer"))
  620.     (zap-directory
  621.          (file-name-as-directory (expand-file-name tex-directory))))
  622.     (save-excursion
  623.       (save-restriction
  624.     (widen)
  625.     (goto-char (point-min))
  626.     (forward-line 100)
  627.     (let ((search-end (point))
  628.           (hbeg (point-min)) (hend (point-min))
  629.           (default-directory zap-directory))
  630.       (goto-char (point-min))
  631.           
  632.           ;; Copy first line, the `\input texinfo' line, to temp file
  633.       (write-region (point) 
  634.                         (save-excursion (end-of-line) (point))
  635.                         tex-out-file nil nil)
  636.           
  637.           ;; Don't copy first line twice if region includes it.
  638.           (forward-line 1)
  639.           (if (< beg (point)) (setq beg (point)))
  640.           
  641.           ;; Initialize the temp file with either the header or nothing
  642.           (if (search-forward tex-start-of-header search-end t)
  643.               (progn
  644.                 (beginning-of-line)
  645.                 (setq hbeg (point))    ; Mark beginning of header.
  646.                 (if (search-forward tex-end-of-header nil t)
  647.                     (progn (beginning-of-line)
  648.                            (setq hend (point)))    ; Mark end of header.
  649.                   (setq hbeg (point-min))))) ; Else no header.
  650.           
  651.           ;; Copy  header  to temp file.
  652.           (write-region (min hbeg beg) hend tex-out-file t nil)
  653.           
  654.           ;; Copy  region  to temp file.
  655.           (write-region (max beg hend) end tex-out-file t nil))
  656.         
  657.         ;; This is  a kludge to insert the tex-trailer into the tex-out-file.
  658.         ;;  We have to create a special buffer in which to insert
  659.         ;;  the tex-trailer first because there is no function with
  660.         ;;  which to append a literal string directly to a file.
  661.         (let ((local-tex-trailer texinfo-tex-trailer))
  662.           (set-buffer temp-buffer)
  663.           (erase-buffer)
  664.           ;; make sure trailer isn't hidden by a comment
  665.           (insert-string "\n")
  666.           (if local-tex-trailer (insert-string local-tex-trailer))
  667.           (tex-set-buffer-directory temp-buffer zap-directory)
  668.           (write-region (point-min) (point-max) tex-out-file t nil))
  669.  
  670. ;;; The following is sufficient in Emacs 19.
  671. ;;;    (write-region (concat "\n" texinfo-tex-trailer) nil
  672. ;;;              tex-out-file t nil)
  673.     ))
  674.     
  675.     (tex-set-buffer-directory "*tex-shell*" zap-directory)
  676.     (tex-send-command tex-shell-cd-command zap-directory)
  677.     (tex-send-command texinfo-tex-command tex-out-file))
  678.   (tex-recenter-output-buffer 0))
  679.  
  680. (defun texinfo-tex-buffer ()
  681.   "Run TeX on visited file, once or twice, to make a correct `.dvi' file."
  682.   (interactive)
  683.  
  684.   ;; Make sure TeX shell is running.
  685.   (require 'tex-mode)
  686.   (if (get-buffer "*tex-shell*")
  687.       (quit-process (get-process "tex-shell") t)
  688.     (tex-start-shell))
  689.  
  690.   (cond ((null buffer-file-name)
  691.          (error "Buffer not visiting any file!"))
  692.         ((buffer-modified-p)
  693.          (error "Buffer has been modified since last saved!")))
  694.  
  695.   (setq tex-zap-file buffer-file-name)
  696.  
  697.   (tex-send-command tex-shell-cd-command (file-name-directory tex-zap-file))
  698.  
  699.   (tex-send-command texinfo-texi2dvi-command tex-zap-file)
  700.  
  701.   (tex-recenter-output-buffer 0))
  702.  
  703. (defun texinfo-texindex ()
  704.   "Run `texindex' on unsorted index files.
  705. The index files are made by \\[texinfo-tex-region] or \\[texinfo-tex-buffer].
  706. This runs the shell command defined by `texinfo-texindex-command'."
  707.   (interactive)
  708.   (require 'tex-mode)
  709.   (tex-send-command texinfo-texindex-command (concat tex-zap-file ".??"))
  710.   (tex-recenter-output-buffer nil))
  711.  
  712. (defun texinfo-tex-print ()
  713.   "Print `.dvi' file made by \\[texinfo-tex-region] or \\[texinfo-tex-buffer].
  714. This runs the shell command defined by `tex-dvi-print-command'."
  715.   (interactive)
  716.   (require 'tex-mode)
  717.   (tex-send-command tex-dvi-print-command (concat tex-zap-file ".dvi"))
  718.   (tex-recenter-output-buffer nil))
  719.  
  720. (defun texinfo-quit-job ()
  721.   "Quit currently running TeX job, by sending an `x' to it."
  722.   (interactive)
  723.   (if (not (get-process "tex-shell"))
  724.       (error "No TeX shell running"))
  725.   (tex-send-command "x"))
  726.  
  727. (defun texinfo-delete-from-print-queue (job-number)
  728.   "Delete job from the line printer spooling queue.
  729. You are prompted for the job number (use a number shown by a previous
  730. \\[texinfo-show-print-queue] command)."
  731.   (interactive "nPrinter job number for deletion: ")
  732.   (require 'tex-mode)
  733.   (if (tex-shell-running)
  734.       (tex-kill-job)
  735.     (tex-start-shell))
  736.   (tex-send-command texinfo-delete-from-print-queue-command job-number)
  737.   (tex-recenter-output-buffer nil))
  738.  
  739. (provide 'texinfo)
  740.  
  741. ;;; texinfo.el ends here
  742.